/*Pravidla základních elementů*/
<NULL>             ::= "NULL" ;  
<TRUE>             ::= "TRUE" ;
<FALSE>            ::= "FALSE" ;
<LETTER>           ::= "_" | "A"-"Z" ;
<STRING>           ::= "\"" (~["\""])* "\""  ;
<DIGIT>            ::= "0"-"9" ;
<NUMINT>           ::= <DIGIT> {<DIGIT>} ;
<NUMDEC>           ::= <DIGIT> {<DIGIT>} "." <DIGIT> {<DIGIT>}  ;
<IDENT>            ::= (<LETTER> {<LETTER> | <DIGIT>}) | "'" {~("'")} "'" ;
<KOD>              ::= (<LETTER> | <DIGIT>) {<LETTER> | <DIGIT>} ;
<VAR>              ::= "$"<IDENT> ;
<DOM>              ::= "@"<IDENT> ;
<PRAGMA>           ::= "#" <IDENT> ["(" (~[")"])* ")"] ; 
<MARGIN>           ::= "MARGIN"; 

<AnyInt>            ::= ["-"] <NUMINT> ;
<AnyNum>            ::= <AnyInt> | (["-"] <NUMDEC>) ;

/*Pravidla zápisu definice proměnných, množin a funkcí */
<Assign>            ::=  <VAR> ":=" <Expression> ;
<SetElm>            ::=  ["^"] <Expression>  ;
<Set>               ::=  ("{" "}") | ("{" <SetElm> {"," <SetElm>} "}") ;
<FunctionCall>      ::=  (<IDENT> "(" ")") | (<IDENT> "(" <Expression> {", " <Expression>} ")") ;

/*Pravidla zápisu  určení datového zdroje výkazů (údajů, parametrů)*/
<Coord>             ::=  <IDENT> | <AnyInt> ;
<RelObd>            ::=  "%" <AnyInt> ;
<IdentRelObd>       ::=  <IDENT> <RelObd> ;
<DataPointVykPart>  ::=  (<IdentRelObd> | <IDENT>) ":"  ;
<DataPoint>         ::=  [<DataPointVykPart>] <IDENT> "[" <Coord> "," <Coord> [ "," ( (<VAR> | <FunctionCall> | <ParConcrList>) | ([( <Coord> ",") ] (<VAR> | <FunctionCall> | <ParConcrList>)) ) ] 
                         "]"  ;
ArrowPoint          ::=  <IDENT> "->" (<IDENT> | <KOD> | <NUMINT>) ;

/*Pravidla zápisu  konkretizace parametrů metapopisu pro určení datového zdroje výkazů*/
<ParConcr>          ::= <IDENT> (":" | "=") (<IDENT> | <KOD> | <NUMINT> | <NUMDEC> | <STRING> | <DOM> | "*" | <NULL> | <Set>)  ;
<ParConcrList>      ::= <ParConcr> {"," <ParConcr>}  ;

/*Pravidla zápisu výrazů*/
<Expression>                ::=  <InExpression> ;
<InExpression>              ::=  <RelationalExpression> ["IN" <RelationalExpression>]  ;
<RelationalExpression>      ::=  <AdditiveExpression> [("<" | ">" | "<=" | ">=" | "=" | "<>") <AdditiveExpression>[<MARGIN> <anyNum>]] ;
<AdditiveExpression>        ::=  <MultiplicativeExpression> [("+" | "-") <MultiplicativeExpression>] ;
<MultiplicativeExpression>  ::=  <UnaryExpression> [("*" | "/") <UnaryExpression>]  ;
<UnaryExpression>           ::=  ["-"] <PrimaryExpression> ;
<Bracketed>                 ::=  "(" <Expression> ")"  ;
 
<PrimaryExpression>         ::= <STRING> | <VAR> | <DOM> | <NULL> | <TRUE> | <FALSE> | <IdentRelObd> | <IDENT> | <AnyNum> | <Set> | <DataPoint> | <ParConcr> | <FunctionCall> | <ArrowPoint> | <Bracketed> | <Expression> ;   

/*Pravidla zápisu kontrolního výrazu*/
<PragmaBlock>     ::= <PRAGMA> {"," <PRAGMA>} 	/*pragma*/ ;
<ForClause>       ::= "FOR" "(" <ParConcrList> ")" <Expression> ;	/*definice opakování kontroly*/
<FilterCheck>     ::= "FILTER_CHECK" "(" <Expression> {"," <Expression>} ")" <Expression>	;	/*definice opakování kontroly na dynamickou množinou*/
<Script>          ::= [<PragmaBlock>] {<Assign>} (<Expression> | <ForClause> | <FilterCheck>) ;	/* definice kontroly*/